// groupnpc.txt
// Exactly like basicnpc, with one difference. When it first spots a foe, sends
// an alert message to everyone in its group. Good for when you have a band of 
// monsters you don't want the party to be able to pick off one at a time.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - Group creature is in.  (You don't need to set this, but it
//     makes life a bit easier.  Leave it at 0 to do nothing.)

begincreaturescript;

variables;

short i,target;
short i_gave_alert = 0;
short rctx,rcty;
short start_hp,end_hp,move,trgt,atktyp;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	if (get_memory_cell(4) > 0)
		add_char_to_group(my_number(),get_memory_cell(4));
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);

	if ((what_group_in(ME) > 0) && (i_gave_alert == 0)) {
		alert_char(1000 + what_group_in(ME));
		i_gave_alert = 1;
		}

break;

beginstate START_STATE; 

	if(get_floor(my_loc_x(),my_loc_y()) != 169)
		erase_char(my_number());
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if (my_dist_from_start() >= 6) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();

break;

beginstate 3; // attacking
	if(get_floor(my_loc_x(),my_loc_y()) != 169)
		erase_char(my_number());
	if ((what_group_in(ME) > 0) && (i_gave_alert == 0)) {
		alert_char(1000 + what_group_in(ME));
		i_gave_alert = 1;
		}
	if (target_ok() == FALSE)
		set_state(START_STATE);
	trgt = (get_target());
	start_hp = get_health(trgt);
	do_attack();
	end_hp = get_health(trgt);
	if(start_hp > end_hp){
		atktyp = get_ran(1,0,14);
		if(atktyp == 0){
			print_str_color("Lightning Strike!",1);
			set_char_status(trgt,11,2,0,0);
			put_effect_on_char(trgt,4,4,0);
			run_animation();
		}
		if(atktyp == 1){
			print_str_color("Blinding Strike!",1);
			set_char_status(trgt,18,5,0,0);
			put_effect_on_char(trgt,10,4,0);
			run_animation();
		}
		if((atktyp > 1) && (atktyp < 4)){
			print_str_color("Addling Strike!",1);
			set_char_status(trgt,13,8,0,0);
			put_effect_on_char(trgt,9,4,2);
			run_animation();
		}
		if((atktyp > 3) && (atktyp < 7)){
			print_str_color("Numbing Strike!",1);
			set_char_status(trgt,3,-6,0,0);
			put_sparkles_on_char(trgt,1,6);
			run_animation();
		}
		if((atktyp > 6) && (atktyp < 11)){
			print_str_color("Cursed Strike!",1);
			set_char_status(trgt,1,-6,0,0);
			put_sparkles_on_char(trgt,6,6);
			run_animation();
		}
		if(atktyp > 10){
			print_str_color("Poison Strike!",1);
			set_char_status(trgt,0,50,0,0);
			put_effect_on_char(trgt,13,1,2);
			run_animation();
		}
	}

break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;